|
|
|
In the first two programs (1A and 1B), the lengths of the data messages are
not known. The sending side (Program 1A) includes the length of each message
as the first two bytes of each message it sends. The receiving side (Program
1B) executes two IPCRECV loops for each message: first to receive the
length and then to receive the data.
The first program (Program 1A):
- looks up the call socket named RALPH located on node JANE and gets back
a destination descriptor;
- creates its own call socket;
- sends a connection request to RALPH;
- shuts down its call socket and its destination socket;
- completes the connection;
- executes a loop in which it:
- reads a line of data;
- stores the length (number of bytes) of the data in the first part
of the message;
- stores the data itself in the second part of the message;
- sends the message on the connection, including the message length
as the first two bytes of the message;
- sends a "last message" which will be recognized by the receiving program
as a termination request;
- receives a "termination confirmation message" and shuts down the
connection by releasing its VC socket.
The second program (Program 1B):
- creates a call socket and names it RALPH;
- waits to receive a connection request;
- shuts down its call socket;
- executes a loop in which it:
- calls a procedure that receives a message by executing two
IPCRECV loops (the first loop determines the incoming
message length and the second loop receives data until all the
pieces of the message have been received);
- prints the message which was received;
- receives a "last message" termination request;
- sends a "termination confirmation message" in response to the
termination request;
- receives a result parameter value of 64 ("REMOTE ABORTED
CONNECTION") in response to a receive request;
- releases its VC socket.
 |
NOTE: 3kRanger made changes marked by
comment {3k} to correct compile errors and simple enhancements. The PDF
manual contains the original code.
Example 1A had a hardcoded Nodename of JANE,
you can see below.
3kRanger added a prompt for Nodename,
where just a return will lookup the and use the local Nodename.
Example 1B will lookup and display the local Nodename; incase you are
running these examples on 2 machines, and don't recall their Nodenames.
|
Program 1A
Download
{NetIPC Example-1-Program 1A}
{ MPEV pascalprep netipc1a,netipc1a.pub;info="set 'native=false'"}
{ MPEiX pasxllk netipc1a,netipc1x.pub,,,"set 'native=true'" }
$list off$
{******************************************************************}
{ Example 1 (programs 1A and 1B) present an example of how to set }
{ up and use a connection (virtual circuit) for TCP access. The }
{ two programs, running on different nodes, open communication via }
{ call sockets. They then establish a connection (using VC sockets)}
{ and send and receive data over this connection. Finally, they }
{ terminate their connection. }
{ }
{ To have netipc1A connect, run netipc1B first. netipc1A prompts }
{ for a Node name. A return looks up the local Node, such that you }
{ can run both program on the same machine. }
{******************************************************************}
$if 'native'$
$standard_level 'HP_PASCAL'$ {3k}
$else$
$standard_level 'HP3000'$ {3k}
$uslinit$ {3k}
$endif$
program connection_example1 ( input, output );
const
maxdata = 2000;
maxmsg = maxdata + 2;
maxname = 20;
maxloc = 52; {3k}
type
$if 'not native'$ {3k}
shortint = -32768..32767; {3k}
$endif$ {3k}
datatype = record
len : shortint;
msg : packed array [1..maxdata] of char;
end;
timeval_type = record case boolean of
true : (int : shortint);
false : (chars : packed array [1..30] of char);
end;
nametype = packed array [1..maxname] of char;
loctype = packed array [1..maxloc] of char;
var
calldesc : integer; {2-word integer}
vcdesc : integer;
protocol : integer;
socket_kind : integer;
dest : integer;
result : integer;
data : datatype;
name : nametype;
location : loctype;
y_len : integer;
y_data : char;
num_msgs : integer;
strdata : string [maxdata];
i : integer;
timeval : timeval_type;
procedure terminate; intrinsic;
{===== NetIPC intrinsic declarations =====}
procedure ipccreate; intrinsic;
procedure ipclookup; intrinsic;
procedure ipcconnect; intrinsic;
procedure ipcrecv; intrinsic;
procedure ipcsend; intrinsic;
procedure ipcshutdown; intrinsic;
procedure ipcerrmsg; intrinsic;
procedure ipccontrol; intrinsic;
{===== error handling procedure =====}
procedure leave ( result : integer; locat : integer ); {3k}
var
msg: string [80];
i, len, newresult: integer;
begin
prompt ( '** ErrLoc ', locat:1, ': ' ); {3k}
ipcerrmsg ( result, msg, len, newresult );
if newresult = 0 then begin
setstrlen (msg, len);
writeln (msg);
end else
writeln ( '** IpcErrMsg result is ', newresult:1 );
terminate;
end;
{===== main of NetIPC Program 1A =====}
begin
{ look up the call socket RALPH located on node JANE }
name:= 'RALPH';
location:= 'JANE';
{===== prompt for or lookup current node ====================== 3k}
location := ' '; {3k}
prompt ( '--Enter Node name or return for local host? ' ); {3k}
{3k}
readln ( strdata ); {3k}
i := strlen ( strdata ); {3k}
strmove ( i, strdata, 1, location, 1 ); {3k}
{3k}
if location [1] <> ' ' then begin {3k}
writeln ( '-- Node: ', location:i ); {3k}
end else begin {3k}
{=== get local/current nodename ===} {3k}
ipccreate ( 3, 0, , , calldesc, result ); {3k}
if result <> 0 then leave ( result, 1 ); {3k}
i := maxloc; {3k}
ipccontrol ( calldesc, 14,,, location, i,, result ); {3k}
if result <> 0 then leave ( result, 2 ); {3k}
ipcshutdown ( calldesc ); {3k}
location [i+1] := ' '; {3k}
writeln ( '--Node: ', location:i, ' --' ); {3k}
end; {3k}
{3k}
writeln ( '--Looking up socket ',name:5,' on Node ', {3k}
location:i,' --'); {3k}
{===== Get Nodename =========================================== 3k}
ipclookup ( name, 5, location, 3, , dest, protocol, socket_kind,
result );
if result <> 0 then leave ( result, 3 ); {3k}
{ create a call socket;
then initiate and complete connection to destination socket}
ipccreate ( socket_kind, protocol, , , calldesc, result );
if result <> 0 then leave ( result, 4 ); {3k}
timeval.int := 100; {tenth seconds} {3k}
ipccontrol ( calldesc, 3, timeval.chars, 2, , , result ); {3k}
if result <> 0 then leave ( result, 5 ); {3k}
{initiate connection}
writeln ( '--Connecting-- ', timeval.int:1, ' tenths' ); {3k}
ipcconnect ( calldesc, dest, , , vcdesc, result );
if result <> 0 then leave ( result, 6 ); {3k}
timeval.int := 0;
timeval.int := 100; {tenth seconds} {3k}
ipccontrol ( vcdesc, 3, timeval.chars, 2, , , result );
if result <> 0 then leave ( result, 7 ); {3k}
ipcshutdown ( calldesc );
ipcshutdown ( dest );
ipcrecv ( vcdesc, , , , , result ); {complete connection}
if result <> 0 then leave ( result, 8 ); {3k}
writeln ( '--Connected--' ); {3k}
{ prompt for messages and send them }
writeln ('Enter "//" to terminate the program.');
setstrlen (strdata, 0);
while strdata <> '//' do begin
prompt ('Message? ');
readln (strdata); {read message}
data.len := strlen (strdata); {store message length}
strmove ( data.len, strdata, 1, data.msg, 1 ); {store message}
{send message with length as first 2 bytes}
ipcsend ( vcdesc, data, data.len +2, , ,result );
if result <> 0 then leave ( result, 9 ); {3k}
end;
{connection shutdown procedure}
data.len := 4;
data.msg := 'END?'; { termination request}
ipcsend ( vcdesc, data, 6, , , result );
writeln ('END sent');
if result <> 0 then leave ( result, 10 ); {3k}
{receive 'Y' confirmation}
y_len := 1;
ipcrecv ( vcdesc, y_data, y_len, , , result );
if (y_data = 'Y') then writeln ('Y received' );
if (y_data = 'Y') and (result = 0) then
ipcshutdown ( vcdesc )
else begin
writeln ( 'Warning: shutdown not confirmed or result 0' );
leave ( result, 11 ); {3k}
end;
end.
Program 1B
Download
{NetIPC Example-1-Program 1B}
{ MPEV pascalprep netipc1b,netipc1b.pub;info="set 'native=false'"}
{ MPEiX pasxllk netipc1b,netipc1y.pub,,,"set 'native=true'" }
$list off$
{******************************************************************}
{ Example 1 (programs 1A and 1B) present an example of how to set }
{ up and use a connection (virtual circuit) for TCP access. The }
{ two programs, running on different nodes, open communication via }
{ call sockets. They then establish a connection (using VC sockets)}
{ and send and receive data over this connection. Finally, they }
{ terminate their connection. }
{ }
{ To have netipc1A connect, run netipc1B first. netipc1A prompts }
{ for a Node name. A return looks up the local Node, such that you }
{ can run both program on the same machine. }
{******************************************************************}
$if 'native'$
$standard_level 'HP_PASCAL'$ {3k}
$else$
$standard_level 'HP3000'$ {3k}
$uslinit$ {3k}
$endif$
program connection_example2 ( output );
const
maxdata = 2000;
maxname = 20;
maxloc = 52; {3k}
type
$if 'not native'$ {3k}
shortint = -32768..32767; {3k}
$endif$ {3k}
datatype = packed array [1..maxdata] of char;
timeval_type = record case boolean of
true : (int : shortint);
false : (chars : packed array [1..30] of char);
end;
nametype = packed array [1..maxname] of char;
loctype = packed array [1..maxloc] of char;
var
calldesc : integer; {2-word integer}
vcdesc : integer;
dlen : integer;
result : integer;
data : datatype;
name : nametype;
len : shortint;
datastr : string [maxdata];
timeval : timeval_type;
port : timeval_type; {3k}
ulen : integer; {3k}
location : loctype; {3k}
procedure terminate; intrinsic;
{===== NetIPC intrinsic declarations =====}
procedure ipccreate; intrinsic;
procedure ipcname; intrinsic;
procedure ipcrecvcn; intrinsic;
procedure ipcrecv; intrinsic;
procedure ipcsend; intrinsic;
procedure ipcshutdown; intrinsic;
procedure ipcerrmsg; intrinsic;
procedure ipccontrol; intrinsic;
{===== error handling procedure =====}
procedure leave ( result : integer; locat : integer ); {3k}
var
msg: string [80];
i, len, newresult: integer;
begin
prompt ( '** ErrLoc ', locat:1, ': ' ); {3k}
ipcerrmsg ( result, msg, len, newresult );
if newresult = 0 then begin
setstrlen (msg, len);
writeln (msg);
end else
writeln ( '** IpcErrMsg result is ', newresult:1 );
terminate;
end;
{ procedure receive }
{ The following procedure receives one message which was sent via
an ipcsend call. It assumes that the length (number of bytes) of
the message was sent as the first two bytes of data and that the
length value does not include those two bytes. }
procedure receive ( connection : integer;
var rbfr : datatype;
var rlen : shortint;
var errorcode : integer );
const
head_len = 2;
type
length_buffer_type = packed array [1..2] of char;
header_len_type = record case integer of
0: ( word: shortint );
1: ( byte: length_buffer_type);
end;
var
i, j : integer;
dlen : integer;
header_len : header_len_type;
tempbfr : datatype;
begin { procedure receive }
i:=0;
errorcode := 0;
while (i <> head_len) and (errorcode = 0) do begin
{ get length of message }
dlen := head_len - i;
ipcrecv ( connection, tempbfr, dlen, , , errorcode );
if errorcode = 0 then begin {3k}
strmove ( dlen, tempbfr, 1, header_len.byte, i+1 );
i := i + dlen;
end; {3k}
end;
rlen := 0; {3k}
if errorcode = 0 then begin
rlen := header_len.word;
i := 0;
{ get the message }
while (i <> rlen) and (errorcode = 0) do begin
dlen := header_len.word - i;
ipcrecv ( connection, tempbfr, dlen, , ,errorcode );
if errorcode = 0 then begin {3k}
strmove ( dlen, tempbfr, 1, rbfr, i+1 );
i := i + dlen;
end; {3k}
end;
end;
end;
{===== main of NetIPC Program 2 or 1B =====}
begin
{create a call socket and name it}
ipccreate ( 3, 4, , , calldesc, result );
if result <> 0 then leave ( result ,1 ); {3k}
name := 'RALPH';
ipcname ( calldesc, name, 5, result );
if result <> 0 then leave ( result, 2 ); {3k}
{===== Get my Nodename ======================================== 3k}
location := ' '; {3k}
dlen := maxloc; {3k}
ipccontrol ( calldesc, 14,,, location, dlen,, result ); {3k}
if result <> 0 then leave ( result, 3 ); {3k}
location [dlen+1] := ' '; {3k}
writeln ( '--Node: ', location:dlen, ' --' ); {3k}
{===== Get Nodename =========================================== 3k}
{===== Get Port number ======================================== 3k}
ipccontrol ( calldesc, 514,,, port.chars, dlen,, result ); {3k}
if result <> 0 then leave ( result, 4 ); {3k}
ulen := port.int; {3k}
if ( ulen < 0 ) then ulen := 65536 + ulen; {3k}
writeln ( '--Port: ', ulen:1, ' name=', name:5, ' --' ); {3k}
{===== Get Port =============================================== 3k}
{wait for a connection request}
timeval.int:=0;
timeval.int:=300; { tenths } {3k}
ipccontrol ( calldesc, 3, timeval.chars, 2, , , result );
if result <> 0 then leave ( result, 5 ); {3k}
writeln ( '--Waiting for connect ',timeval.int:1,' tenths');{3k}
ipcrecvcn ( calldesc, vcdesc, , , result );
if result <> 0 then leave ( result, 6 ); {3k}
ipcshutdown ( calldesc );
writeln ( '-- Connected --' ); {3k}
{wait for a message on the connection and print message received}
{set timeout}
timeval.int:=0;
timeval.int:=100; { tenths } {3k}
ipccontrol ( vcdesc, 3, timeval.chars, 2, , , result );
if result <> 0 then leave ( result, 7 ); {3k}
writeln ( '-- Wait ', timeval.int:1, ' tenths' ); {3k}
repeat begin
receive ( vcdesc, data, len, result );
if result <> 0 then leave ( result, 8 ); {3k}
setstrlen (datastr, len);
strmove ( len, data, 1, datastr, 1 );
if datastr <> 'END?' then
writeln (datastr); {print data received}
end until datastr = 'END?';
{connection shutdown procedure}
if datastr = 'END?' then writeln ('END received');
data := 'Y';
ipcsend ( vcdesc, data, 1, , , result ); {confirmation message}
writeln ('Y sent');
if result <> 0 then leave ( result, 9 ); {3k}
receive ( vcdesc, data, len, result );
if result = 64 then
ipcshutdown ( vcdesc )
else
leave ( result, 10 ); {3k}
end.
Program 1C
3kRanger provides
a modified Program 1B with IOWAIT and Control-Y interrupt
allowing you to interrupt IPCRECVCN waiting for a connection.
Download
If you run Example 1B, and cannot make a connection from Example 1A,
your program is blocked until you [Break] and Abort to get out of the program.
Program 1C uses IOWAIT so as not to block in IPCRECVCN.
IOWAIT can be interrupted with a user Control-Y trap and the I/O
aborted.
3kRanger Runtime Example
Two sessions on the same machine. 1B should be run before 1A.
Fox 25:netipc1b.pub
--Node: FOX.TKRANGER.COM --
--Port: 59204 name=RALPH --
--Waiting for connect 300 tenths
-- Connected --
-- Wait 100 tenths
test message
//
END received
Y sent
Fox 25:
Fox 9:netipc1a.pub
--Enter Node name or return for local host? [Return]
--Node: FOX.TKRANGER.COM --
--Looking up socket RALPH on Node FOX.TKRANGER.COM --
--Connecting-- 100 tenths
--Connected--
Enter "//" to terminate the program.
Message? test message
Message? //
END sent
Y received
Fox 9:
Fox 9:netipc1c.pub
--Node: FOX.TKRANGER.COM --
--Port: 59238 name=RALPH --
!! Control-Y set
--Waiting for connect 300 tenths
!! Control-Y (1) !! [Control-Y]
Fox 9:
|
